(*サイトiにおけるスピン演算子σ^a_i*)
Do[σ[i,a]=KroneckerProduct@@Join[Table[PauliMatrix[0],{x,0,i-1}],{PauliMatrix[a]},Table[PauliMatrix[0],{x,i+1,6}]],{i,0,6},{a,0,3}];
id(*項等演算子*)=σ[0,0];

(*Levin-Gu模型*)
B=I/8*σ[0,1].(id-I σ[1,3].σ[2,3]).(id-I σ[2,3].σ[3,3]).(id-I σ[3,3].σ[4,3]).(id-I σ[4,3].σ[5,3]).(id-I σ[5,3].σ[6,3]).(id-I σ[6,3].σ[1,3]);

(*2単体部分のユニタリ変換*)
u[i_,j_,k_]:=1/8*((id+σ[i,3]).(id+σ[j,3]).(id+σ[k,3])+x*y*(id+σ[i,3]).(id+σ[j,3]).(id-σ[k,3])+x^(-1)*y^(-1)*(id+σ[i,3]).(id-σ[j,3]).(id+σ[k,3])+(id+σ[i,3]).(id-σ[j,3]).(id-σ[k,3])+y*(id-σ[i,3]).(id+σ[j,3]).(id+σ[k,3])-x^(-1)*(id-σ[i,3]).(id+σ[j,3]).(id-σ[k,3])+x*(id-σ[i,3]).(id-σ[j,3]).(id+σ[k,3])+y^(-1)*(id-σ[i,3]).(id-σ[j,3]).(id-σ[k,3]));

(*Branching str [a]*)
Clear[α,β];
x=E^(I α);y=E^(I β);
U=Simplify[u[0,1,2].u[0,3,2]\[ConjugateTranspose].u[4,0,3].u[5,4,0]\[ConjugateTranspose].u[5,6,0].u[6,0,1]\[ConjugateTranspose],{α,β}∈Reals];
Solve[U.σ[0,1]==B.U,{α,β}]

(*Branching str [b]*)
Clear[α,β];
x=E^(I α);y=E^(I β);
U=Simplify[u[0,1,2].u[0,2,3].u[0,3,4].u[0,4,5].u[0,5,6].u[0,6,1],{α,β}∈Reals];
Solve[U.σ[0,1]==B.U,{α,β}]

(*Levin-Gu App. B*)
v[0,0,0,0]=1;
v[0,0,0,1]=-I;
v[0,1,0,0]=-I;
v[0,0,1,0]=-I;
v[0,1,1,1]=-I;
v[0,1,0,1]=-1;
v[0,1,1,0]=-1;
v[0,0,1,1]=-1;
Do[ω[a,b,c]=v[0,a,Mod[a+b,2],Mod[a+b+c,2]],{a,0,1},{b,0,1},{c,0,1}]
Table[ω[b,c,d]/ω[Mod[a+b,2],c,d]*ω[a,Mod[b+c,2],d]/ω[a,b,Mod[c+d,2]]*ω[a,b,c],{a,0,1},{b,0,1},{c,0,1},{d,0,1}]

u[i_,j_,k_]:=(Cos[3*θ]*id+I*Sin[3*θ]*σ[i,3].σ[j,3].σ[k,3]).(Cos[θ]*id-I*Sin[θ]*σ[i,3]).(Cos[θ]*id-I*Sin[θ]*σ[j,3]).(Cos[θ]*id-I*Sin[θ]*σ[k,3])

θ=Pi/24;
U=u[0,1,2].u[0,2,3].u[0,3,4].u[0,4,5].u[0,5,6].u[0,6,1]//Simplify;
U.σ[0,1].U\[ConjugateTranspose]==B//Simplify
U.σ[0,1].U\[ConjugateTranspose]//Simplify//MatrixForm