###############
# omega range #
###############

omega_min=0
omega_max=200

set logscale x


###################
# common settings #
###################

set terminal postscript eps enhanced color "Helvetica,24"
set key right top

set xrange [omega_min:omega_max]

set style line 1 lw 3 lc "red"
set style line 2 lw 3 lc "blue"
set style line 3 lw 3 lc "dark-green"

set xlabel '{/Symbol w} [eV]'



########
# EELS #
########

set ylabel "-Im {/Symbol e}(0,{/Symbol w})^{-1}"

set output "eels.eps"
plot 'dat.eels-x' using 1:2 title "x" with lines ls 1,\
     'dat.eels-y' using 1:2 title "y" with lines ls 2,\
     'dat.eels-z' using 1:2 title "z" with lines ls 3



###################################
# Macroscopic dielectric function #
###################################

set ylabel "Macroscopic dielectric function"

set output "macroscopic_epsilon-x.eps"
plot 'dat.macroscopic_epsilon-x' using 1:2 title "Re {/Symbol e}^{-1}" with lines ls 1,\
     'dat.macroscopic_epsilon-x' using 1:3 title "Im {/Symbol e}^{-1}" with lines ls 2

set output "macroscopic_epsilon-y.eps"
plot 'dat.macroscopic_epsilon-y' using 1:2 title "Re {/Symbol e}^{-1}" with lines ls 1,\
     'dat.macroscopic_epsilon-y' using 1:3 title "Im {/Symbol e}^{-1}" with lines ls 2

set output "macroscopic_epsilon-z.eps"
plot 'dat.macroscopic_epsilon-z' using 1:2 title "Re {/Symbol e}^{-1}" with lines ls 1,\
     'dat.macroscopic_epsilon-z' using 1:3 title "Im {/Symbol e}^{-1}" with lines ls 2



########################
# Optical conductivity #
########################

set ylabel "Optical conductivity [10^6/{/Symbol W}/m]"

set output "optcond-x.eps"
plot 'dat.optical_conductivity-x' using 1:2 title "Re {/Symbol s}({/Symbol w})" with lines ls 1,\
     'dat.optical_conductivity-x' using 1:3 title "Im {/Symbol s}({/Symbol w})" with lines ls 2

set output "optcond-y.eps"
plot 'dat.optical_conductivity-y' using 1:2 title "Re {/Symbol s}({/Symbol w})" with lines ls 1,\
     'dat.optical_conductivity-y' using 1:3 title "Im {/Symbol s}({/Symbol w})" with lines ls 2

set output "optcond-z.eps"
plot 'dat.optical_conductivity-z' using 1:2 title "Re {/Symbol s}({/Symbol w})" with lines ls 1,\
     'dat.optical_conductivity-z' using 1:3 title "Im {/Symbol s}({/Symbol w})" with lines ls 2



################
# Reflectivity #
################

set ylabel "Reflectivity"

set output "reflectivity.eps"
plot 'dat.reflectivity-x' using 1:2 title "x" with lines ls 1,\
     'dat.reflectivity-y' using 1:2 title "y" with lines ls 2,\
     'dat.reflectivity-z' using 1:2 title "z" with lines ls 3

exit